blob: c3155a713762ea2fdd699652cc26b57d147e2e82 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
|
OUTPUT_DIR_NAME = output
export(OUTPUT_DIR_NAME)
DESTDIR = $$PWD/../$$OUTPUT_DIR_NAME/SQLiteStudio
OBJECTS_DIR = $$PWD/../$$OUTPUT_DIR_NAME/build
MOC_DIR = $$PWD/../$$OUTPUT_DIR_NAME/build
UI_DIR = $$PWD/../$$OUTPUT_DIR_NAME/build
LIBS += -L$$DESTDIR
macx: {
QMAKE_CXXFLAGS += -Wno-gnu-zero-variadic-macro-arguments -Wno-overloaded-virtual
INCLUDEPATH += $$PWD/../../include
LIBS += -L$$PWD/../../lib
}
win32: {
INCLUDEPATH += $$PWD/../../include
LIBS += -L$$PWD/../../lib
}
INCLUDEPATH += $$PWD/coreSQLiteStudio
DEPENDPATH += $$PWD/coreSQLiteStudio
contains(QT, gui): {
INCLUDEPATH += $$PWD/guiSQLiteStudio $$PWD/../$$OUTPUT_DIR_NAME/build/guiSQLiteStudio
DEPENDPATH += $$PWD/guiSQLiteStudio
}
win32|macx: {
CONFIG += portable
}
portable {
QMAKE_LFLAGS += -Wl,-rpath,.
linux: {
LIBS += -L$$DESTDIR/lib
}
}
unix: {
isEmpty(LIBDIR) {
LIBDIR = $$PREFIX/lib
}
export(LIBDIR)
isEmpty(BINDIR) {
BINDIR = $$PREFIX/bin
}
export(BINDIR)
}
# Enable automatic translation files processing globally
QMAKE_RESOURCE_FLAGS += -name $${TARGET}_${QMAKE_FILE_BASE}
TRANSLATIONS += $$files($$_PRO_FILE_PWD_/translations/*.ts)
defined(TARGET, "var") {
DEFINES += "PROJECT_MODULE_NAME=$${TARGET}"
}
!isEmpty(TRANSLATIONS) {
CONFIG += lrelease embed_translations
QM_FILES_RESOURCE_PREFIX = /msg/translations
}
|
