Import Upstream version 0.8upstream/0.8

1 files changed, 36 insertions, 0 deletions

diff --git a/qt5gtk2.pro b/qt5gtk2.pro
new file mode 100644
index 0000000..ce96778
--- /dev/null
+++ b/qt5gtk2.pro
@@ -0,0 +1,36 @@
+#Qt version check (taken from QtCreator)
+defineTest(minQtVersion) {
+    maj = $$1
+    min = $$2
+    patch = $$3
+    isEqual(QT_MAJOR_VERSION, $$maj) {
+        isEqual(QT_MINOR_VERSION, $$min) {
+            isEqual(QT_PATCH_VERSION, $$patch) {
+                return(true)
+            }
+            greaterThan(QT_PATCH_VERSION, $$patch) {
+                return(true)
+            }
+        }
+        greaterThan(QT_MINOR_VERSION, $$min) {
+            return(true)
+        }
+    }
+    greaterThan(QT_MAJOR_VERSION, $$maj) {
+        return(true)
+    }
+    return(false)
+}
+
+!minQtVersion(5, 7, 0) {
+    message("Cannot build Qt5Gtk2 with Qt version $${QT_VERSION}.")
+    error("Use at least Qt 5.7.0.")
+}
+
+TEMPLATE = subdirs
+
+SUBDIRS += src/qt5gtk2-qtplugin src/qt5gtk2-style
+
+include(qt5gtk2.pri)
+
+message (PLUGINDIR=$$PLUGINDIR)