From 7167ce41b61d2ba2cdb526777a4233eb84a3b66a Mon Sep 17 00:00:00 2001
From: Unit 193 <unit193@ubuntu.com>
Date: Sat, 6 Dec 2014 17:33:25 -0500
Subject: Imported Upstream version 2.99.6

---
 SQLiteStudio3/SQLiteStudio3.pro | 46 +++++++++++++++++++++++++++++++++++++++++
 1 file changed, 46 insertions(+)
 create mode 100644 SQLiteStudio3/SQLiteStudio3.pro

(limited to 'SQLiteStudio3/SQLiteStudio3.pro')

diff --git a/SQLiteStudio3/SQLiteStudio3.pro b/SQLiteStudio3/SQLiteStudio3.pro
new file mode 100644
index 0000000..66efea7
--- /dev/null
+++ b/SQLiteStudio3/SQLiteStudio3.pro
@@ -0,0 +1,46 @@
+TEMPLATE = subdirs
+
+core.subdir = coreSQLiteStudio
+
+tests.subdir = Tests
+tests.depends = core
+
+gui.subdir = guiSQLiteStudio
+gui.depends = core
+
+cli.subdir = sqlitestudiocli
+cli.depends = core
+
+gui_app.subdir = sqlitestudio
+gui_app.depends = gui
+
+update_app.subdir = UpdateSQLiteStudio
+update_app.depends = core
+
+SUBDIRS += \
+    core \
+    gui \
+    cli \
+    gui_app
+
+if(contains(DEFINES,tests)) {
+    SUBDIRS += tests
+}
+
+win32: {
+    SUBDIRS += update_app
+}
+
+linux: {
+    portable.commands = sh $$PWD/create_linux_portable.sh $$PWD/../output $$QMAKE_QMAKE
+    tgz.commands = sh $$PWD/create_linux_portable.sh $$PWD/../output $$QMAKE_QMAKE tgz
+    dist.commands = sh $$PWD/create_linux_portable.sh $$PWD/../output $$QMAKE_QMAKE dist
+    QMAKE_EXTRA_TARGETS += portable tgz dist
+}
+
+macx: {
+    bundle.commands = sh $$PWD/create_macosx_bundle.sh $$PWD/../output $$QMAKE_QMAKE
+    dmg.commands = sh $$PWD/create_macosx_bundle.sh $$PWD/../output $$QMAKE_QMAKE dmg
+    dist.commands = sh $$PWD/create_macosx_bundle.sh $$PWD/../output $$QMAKE_QMAKE dist
+    QMAKE_EXTRA_TARGETS += bundle dmg dist
+}
-- 
cgit v1.2.3